外賣記錄教程總共有3步,

但其實兩者並無關係,

只是通過同一個實例來展現公式,

如果有興趣的可移步 :

用EXCEL製作外賣記錄表第1步--為每個訂飯人新增一個資料頁[SUM()][根據儲存格資料生成工作表]

[VBA]Excel巨集的應用(3)--單純錄製巨集實例 (用EXCEL製作外賣記錄表第3步) [巨集][Macro][宏][VBA][移除重複項][注釋(')][Offset()][End(xlDown)]

 

先前說到如果同事有300多人,

而每位同事都有自己專屬的工作表,

那要找到相應的工作表實在非常困難且浪費時間的事,

此時就可用到超連結功能[HYPERLINK()]

 

目錄

一. 最一般(小白)的插入超連結-右鍵>連結

二. 超連結函數-HYPERLINK()介紹

三. 實例應用,用HYPERLINK()批量建立超連結

(本來想弄錨點的,不過錨點連好像只能開新頁,不可以頁內跳轉,不想研究,無奈放棄了。)

 

一. 最一般(小白)的插入超連結-右鍵>連結

右鍵>連結>插入超連結

然後選擇自己想連結的文件、文件夾、網址、電郵就可以了。

 

二. 超連結函數-HYPERLINK()

第1個方法簡單到不用學,任何一個用過電腦的人應該都能自己摸索出來,

但說實話,某君之前也只會這種,

因為於某君而言,超連結的使用頻率不算太高,

有這麼一個笨辦法就夠用了,

但某一天,同事K說希望在Document Register裡面可以有連結直接連到文件所在的文件夾中,

效果示意圖

文件不多,大概幾千個而已,

難道要在每一條記錄中[右鍵>連結>插入超連結]嗎?

懶惰君的世界霎時天昏地暗、日月無色。

幸好,某君深知世界不會這麼殘忍、EXCEL也不會如此愚蠢,

緊記,批量重覆、有規律的工作正是EXCEL(電腦、機器等等亦如是)最擅長的事,

只要一出現上述關鍵詞,又是公式出現的好時候。

果然一查,超連結函數HYPERLINK()就出來了。

再用函數簡化工作之前,先全面了解一下函數吧。

 

=HYPERLINK(link_location,[friendly_name])

=HYPERLINK(路徑,[顯示名稱](可省略))

路徑可以是網址、電郵、文件路徑、文件夾路徑等。

路徑需要完整地、一字不錯地回饋,需加上雙引號(""),把整個路徑直接當成文字形式就好了。

 

1. 網址

【顯示結果】 【公式】
【4NGus懶人筆記 =HYPERLINK("http://dressing2k.pixnet.net/blog","【4NGus懶人筆記")
http://dressing2k.pixnet.net/blog =HYPERLINK("http://dressing2k.pixnet.net/blog")

點擊兩個結果都會連結至同一網站,如果省略顯示名稱,則直接顯示路徑

 

2. 電郵

【顯示結果】 【公式】
aachan@gmail.com =HYPERLINK("mailto:aachan@gmail.com","aachan@gmail.com")
mailto:aachan@gmail.com =HYPERLINK("mailto:aachan@gmail.com")

*電郵前需加"mailto:"

 

3. 文件夾及文件

【顯示結果】 【公式】
文件 =HYPERLINK("C:\Users\user\Documents","文件")
binder.pdf =HYPERLINK("C:\Users\user\Documents\binder.pdf","binder.pdf")

 

4. Excel中的位置 (包括跳轉到不同的工作表不同的儲存格)

=HYPERLINK("[C:\Users\user\Desktop\新增 Microsoft Excel 工作表.xlsx]工作表1!A1")
功能描述打開文件[新增 Microsoft Excel 工作表.xlsx],並停留在[工作表1]的[A1]儲存格。
=HYPERLINK("#工作表1!A1")
功能描述移至當前Excel的[工作表1],並停留在[A1]儲存格。

*Excel的路徑及名稱需用[ ]括上

*若要移至當前Excel的其它位置,路徑及名稱可用#代替

 

三. 以外賣記錄表為例,用HYPERLINK()批量建立超連結

1. 由[外賣資料頁]連結至[同事個人資料頁]—批量連結至Excel中的位置

上回已創建了相關工作表

樣式分別是這樣的:

希望按AA的名字就自動跳轉到AA的資料頁中(即上述的第4點,Excel中的位置),用公式的話就是:

= HYPERLINK("[D:\外賣記錄.xlsx]AA!A2","AA") (打開 D盤 的 excel [外賣記錄.xlsx],並移至 [AA] 工作表的 [A2] 儲存格,顯示值[AA])

或以#取代整個路徑(需與目的工作表在同一個excel當中):

= HYPERLINK("#AA!A2","AA")

以此類推,剩下的公式就是:

= HYPERLINK("#BB!A2","BB")

= HYPERLINK("#CC!A2","CC")

= HYPERLINK("#KK!A2","KK")

仔細看來,其實除了同事的名字外其無不同,只需在[B2]中輸入= HYPERLINK("#"&A2&"!A2",A2)

  A B
1 Name 公式
2 AA = HYPERLINK("#"&A2&"!A2",A2)
3 BB = HYPERLINK("#"&A3&"!A2",A3)
4 CC = HYPERLINK("#"&A4&"!A2",A4)
5 DD =HYPERLINK("#"&A5&"!A2",A5)
6 EE = HYPERLINK("#"&A6&"!A2",A6)
7 FF = HYPERLINK("#"&A7&"!A2",A7)
8 GG = HYPERLINK("#"&A8&"!A2",A8)
9 HH = HYPERLINK("#"&A9&"!A2",A9)
10 II = HYPERLINK("#"&A10&"!A2",A10)
11 KK = HYPERLINK("#"&A11&"!A2",A11)

 

再向下一拉就可以了,不管是300還是1000位同事都可以輕易搞定!

一按[DD]就會彈至DD的資料頁,效果如圖 (到底要如何用圖片表達。。。某君要變一點GIF出來。。。有空的時候):

 

 

2. 輕鬆打開[餐飲單據]—批量連結至文件

一理通,百理明,相信各位聰明的寶寶們也可以用上述的例子稍加改變做到。

假設所有的[餐飲單據]都放在D盤的[receipt]文件夾中,以日期命名,而格式全是pdf,那我們就可以利用[日期]列來創造連結,

公式很簡單,就是。。。大家都在上圖偷看到了吧~

 

【顯示結果】 【公式】
20180803.pdf =HYPERLINK("D:\receipt\20180803.pdf","20180803.pdf")

如何將上面的公式套用至所有日期呢?

  • 日期的格式有很多,為了與我們存檔的名字一致,首先要將日期變成文字格式:
=TEXT(S2,"yyyymmdd")

S2=日期所在儲存格;yyyymmdd=年月日8位顯示格式

  • 然後把文件夾路徑,如D:\receipt\ ,儲存在某一個儲存格中,如B1。也可以不儲存,直接嵌進公式,不過這樣不利於更改。
  • 最後把公式連在一起=HYPERLINK(B1&TEXT(S2,"yyyymmdd")&".pdf")

P.S. 因為B1應該是固定不動的,拉公式之前記得先鎖起來。(按 [F4] 令其變成 $B$1)

 

小TIPS

**如果不想自己動手查文件路徑,可以用=CELL("filename")查詢。

4ngus 發表在 痞客邦 留言(1) 人氣()